acertmgr/docs/archlinux/python-acertmgr/PKGBUILD

pkgname=python-acertmgr
_pkgname=acertmgr
pkgver=v0.0.0
pkgrel=1
pkgdesc='An automated certificate manager using ACME/letsencrypt'
arch=('any')
url='https://github.com/moepman/acertmgr'
license=('ISC')
depends=('python-cryptography>=0.6')
optdepends=('python-yaml: Support config files in YAML format'
            'python-idna: Support conversion of unicode domains'
            'python-dnspython: Support for dns challenge handlers'
            'python-cryptography>=2.1: Support for the OCSP must-staple flag'
            'python-cryptography>=2.6: Support for Ed25519 key support'
	   )
makedepends=('git')
conflicts=('python-acertmgr')
provides=('python-acertmgr')
source=('git://github.com/moepman/acertmgr.git')
md5sums=('SKIP')

pkgver() {
  cd $_pkgname
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd $_pkgname
  python setup.py build
}

package() {
  cd $_pkgname
  python setup.py install --root=${pkgdir} --optimize=1
}