acertmgr/docs/archlinux/python2-acertmgr/PKGBUILD

pkgname=python2-acertmgr
_pkgname=acertmgr
pkgver=v0.0.0
pkgrel=1
pkgdesc='An automated certificate manager using ACME/letsencrypt'
arch=('any')
url='https://github.com/moepman/acertmgr'
license=('ISC')
depends=('python2-cryptography>=0.6')
optdepends=('python2-yaml: Support config files in YAML format'
            'python2-idna: Support conversion of unicode domains'
            'python2-dnspython: Support for dns challenge handlers'
            'python2-cryptography>=2.1: Support for the OCSP must-staple flag'
            'python2-cryptography>=2.6: Support for Ed25519 key support'
	   )
makedepends=('git')
conflicts=('python-acertmgr')
provides=('python-acertmgr')
source=('git://github.com/moepman/acertmgr.git')
md5sums=('SKIP')

pkgver() {
  cd $_pkgname
  git describe --long --tags | sed 's/\([^-]*-g\)/r\1/;s/-/./g'
}

build() {
  cd $_pkgname
  python2 setup.py build
}

package() {
  cd $_pkgname
  python2 setup.py install --root=${pkgdir} --optimize=1
}